Internet

HTTP Download File

You can use the HTTPPage command to download a file from a web server. The trick is to remove the header from the file before saving it to the local computer.

The following sample code downloads a zip file and prompts the user for a file name and location to save the file.

; Ping the server to make sure we are connected to the internet.
Calculate Server as 'studiotips.net'
TCPPing (Server) Returns Milliseconds
If Milliseconds<0
   OK message (Icon) {Unable to ping the server at '[Server]'}
   Calculate FlagOK as kFalse
Else
   
   ; Figure out the URL to the file to be downloaded.
   ; The file could be any file type: zip, pdf, jpg, txt, etc.
   Calculate DownloadsDirURL as 'http://www.studiotips.net/downloads/free/'
   Calculate FileName as 'test.zip'
   Calculate URL as con(DownloadsDirURL,FileName)
   
   ; Load the file into a character variable.
   HTTPPage (URL) Returns Buffer
   If len(Buffer)=0
      OK message (Icon) {The server returned an empty page for the URL:////[URL]}
      Calculate FlagOK as kFalse
   Else
      
      ; Remove the HTTP header and copy the character variable contents to a binary variable.
      ; The header is separate from the content by an empty line.
      Calculate Find as con(kCr,kLf,kCr,kLf)
      Calculate Binary as mid(Buffer,pos(Find,Buffer)+len(Find))
      
      ; Prompt the user for a file name and location to save the file.
      Calculate Path as FileName
      ; (path[,prompt,filter,initial-directory,appflags])
      Do FileOps.$putfilename(Path,'Save Downlioaded File As') Returns bContinue
      If not(bContinue)
         Calculate FlagOK as kTrue
      Else
         
         ; Create the file using the FileOps external.
         Do oFileOpsExt.$createfile(Path) Returns FlagOK
         If FlagOK
            Do oFileOpsExt.$writefile(Binary) Returns FlagOK
         End If
         Do oFileOpsExt.$closefile()
         If not(FlagOK)
            OK message (Icon) {FileOps error when attempting to create and write to the file at:////[Path]}
         Else
            OK message (Icon) {The downloaded file has been saved at:////[Path]}
         End If
      End If
   End If
End If
Quit method FlagOK

HTTPPage

The Omnis command HTTPPage returns the contents of a web page.

; Ping the server to make sure we are connected to the internet.
Calculate Server as 'studiotips.net'
TCPPing (Server) Returns Milliseconds
If Milliseconds<0
   OK message (Icon) {Unable to ping the server at '[Server]'}
Else
   
   ; Get the home page contents.
   Calculate URL as 'http://www.studiotips.net'
   HTTPPage (URL) Returns Text
   
   OK message (Icon) {StudioTips home page content is:////[Text]}
   Breakpoint {Right-click on the Text variable to see the full contents.}
   
End If
Quit method Text

Open Web Browser to URL

This tip provides cross platform code for opening the default web browser and pointing it to a specified URL. The Go to URL button in the StudioTips Browser window uses this code.

You can copy the sample code included with this tip to your library.

; Open the default browser to a specified URL.
Switch sys(6)
      
   Case 'M','X' ;; Mac, Mac OS X
      
      Calculate ScriptText as con('open location "',iMyURL,'"')
      Calculate ScriptText as con('$runapplescript(',chr(39),ScriptText,chr(39),')')
      Do [ScriptText]
      
   Case 'W','N' ;; Windows, Windows NT or 2000
      
      Register DLL ('Shell32.dll','ShellExecuteA','JJCCCCJ') Returns ErrorCode
      Call DLL ('Shell32.dll','ShellExecuteA',0,'#NULL#',iMyURL,'','#NULL#',1)
      
   Default
      
      OK message [sys(85)] (Icon) {Sorry I don't know how to open your Internet browser}
      
End Switch

FTP

Omnis has a whole group of FTP commands which you can use.

FTPChmod
FTPConnect
FTPCwd
FTPDelete
FTPDisconnect
FTPGet
FTPGetBinary
FTPGetLastStatus
FTPList
FTPMkdir
FTPPut
FTPPutBinary
FTPPwd
FTPReceiveCommandReplyLine
FTPRename
FTPSendCommand
FTPSetConfig
FTPSite
FTPType

You can look up information on each of these command in the F1 Help.

The StudioTips tipBase library contains an object class called, oFTP. I use the oFTP object for uploading the StudioTips documentation to the studiotips.net website and for the AutoUpdater utility.

The oFTP object class acts as an adapter to the Omnis FTP commands, making it easy for you to setup and use FTP in your application. You don't have to study all the Omnis FTP commands. You simply use the public methods of oFTP and it executes the FTP command for you. StudioTips members are welcome to copy the oFTP object class to their own applications.

After you instantiate the oFTP object using an object datatype variable of the scope of your choice you send it an $initialize message. The $initialize message includes parameters that specify the server, user name, password, etc. Once the object has been initialized it knows the server, user name and password, so you don't need to supply that information as you call the various public methods of oFTP.

If an error occurs, the error information is copied to an iErrText ivar of the oFTP object class, and kFalse is returned to the sender. The FTP error code is looked up and the user readabble FTP error text is appended to the iErrText. An $:ErrorText method returns the current value of iErrText to the sender. The oFTP object will also check if your application uses an oErrorHandler object instantiated by the startup task variable errhndlr, and if you do, oFTP will send a $logError or $logFTPError to your error handler.

The following is some sample code of how you might use the oFTP error handler object.

Calculate ServerAddr as 'studiotips.net'
Calculate UserName as 'temp@studiotips.net'
Calculate Password as 'pass'
Calculate PortNum as ''
Calculate InitialDir as ''
Calculate PingTimeOutSeconds as 0 ;; Don't use TCPPing
; (pServerAddr,pUserName,pPassword,pPortNum_opt,pInitialDir_opt,pPingTimeoutSeconds_opt)
Do oFTP.$initialize(ServerAddr,UserName,Password,PortNum,InitialDir,PingTimeOutSeconds) Returns FlagOK
If FlagOK
   
   Do oFTP.$connect() Returns FlagOK
   If FlagOK
      
      Do oFTP.$:PathWorkingDir() Returns FolderPath
      
      Do oFTP.$:FilesList_longformat() Returns FilesList
      If FilesList.$colcount=0
         Calculate FlagOK as kFalse
      Else
         OK message oFTP Object Class (Icon) {There are [FilesList.$linecount] files and/or directories found in the [FolderPath] directory on the [ServerAddr] server for the FTP user [UserName]}
      End If
   End If
End If
If not(FlagOK)
   Do oFTP.$:ErrorText() Returns ErrText
   OK message FTP Error (Icon) {[ErrText]}
End If
Quit method FlagOK

TCP

Omnis has a whole group of TCP commands which you can use.

TCPAccept
TCPAddr2Name
TCPBind
TCPBlock
TCPClose
TCPConnect
TCPGetMyAddr
TCPGetMyPort
TCPGetRemoteAddr
TCPListen
TCPName2Addr
TCPPing
TCPReceive
TCPSend
TCPSocket

You can look up information on each of these command in the F1 Help.

TCPName2Addr

Use the TCPName2Addr Omnis command to convert a domain name to an IP address.

TCPName2Addr (hostname) Returns address

; Note: IPAddr will be an error code number if the hostname could not be looked up.

; Test with the vencor.ca domain.
Calculate HostName as 'vencor.ca'

TCPName2Addr (HostName) Returns IPAddr
If isnumber(IPAddr)
   OK message TCPName2Addr (Icon) {Unable to get a valid IP address for the host name '[HostName]'}
Else
   OK message TCPName2Addr (Icon) {The IP address for the host name '[HostName]' is '[IPAddr]'}
End If

Note: This command fails if the address of a Domain Name Server has not been defined in your computer. Not all host IP Addresses may be known to the Domain Name Server. If the Domain Name Server is busy or unavailable, the command times out and returns an error. Defining often-used servers to a local hostŐs file or using a caching Domain Name Server increases performance of this command.

I tested to see what this method does if you feed it an IP address rather than a domain name. If the IP address is a valid format, the method simply returns the IP address. If the IP address is not a valid format, e.g. one of the numbers is greater than 255, the method returns and error.

; Test with the IP address of the vencor.ca domain from the previous code snip.
Calculate HostName as IPAddr

TCPName2Addr (HostName) Returns IPAddr
If isnumber(IPAddr)
   OK message TCPName2Addr (Icon) {Unable to get a valid IP address for the host name '[HostName]'}
Else
   OK message TCPName2Addr (Icon) {The IP address for the host name '[HostName]' is '[IPAddr]'}
End If


; Test with an valid IP address that likely doesn't exist.
Calculate HostName as '192.255.254.253'

TCPName2Addr (HostName) Returns IPAddr
If isnumber(IPAddr)
   OK message TCPName2Addr (Icon) {Unable to get a valid IP address for the host name '[HostName]'}
Else
   OK message TCPName2Addr (Icon) {The IP address for the host name '[HostName]' is '[IPAddr]'}
End If


; Test with an invalid IP address.
Calculate HostName as '192.168.1.258'

TCPName2Addr (HostName) Returns IPAddr
If isnumber(IPAddr)
   OK message TCPName2Addr (Icon) {Unable to get a valid IP address for the host name '[HostName]'}
Else
   OK message TCPName2Addr (Icon) {The IP address for the host name '[HostName]' is '[IPAddr]'}
End If

Click the Run Demo button in the StudioTips Browser window to run the sample code.

TCPPing

Use the TCPPing Omnis command to ping a server.

TCPPing (hostname[,size,timeout]) Returns milliseconds

; Test with the vencor.ca domain.
Calculate HostName as 'vencor.ca'

; (Hostname[,Size,Timeout])
TCPPing (HostName) Returns Milliseconds
If Milliseconds<0
   OK message TCPPing (Icon) {TCPPing to [HostName] failed.}
Else
   OK message TCPPing (Icon) {TCPPing to [HostName] succeeded.}
End If

; Test with an invalid domain name.
Calculate HostName as 'vencor.xyz'

TCPPing (HostName) Returns Milliseconds
If Milliseconds<0
   OK message TCPPing (Icon) {TCPPing to [HostName] failed.}
Else
   OK message TCPPing (Icon) {TCPPing to [HostName] succeeded.}
End If

The problem I have run into with using TCPPing is that numerous servers ignore TCP ping on purpose. e.g. Try pinging apple.com

You can not assume that a server is going to respond when you send it a TCPPing.

I was using TCPPing to test communication with a host before attempting to do an SMTPSend, and FTPConnect, or $logon to a database.

If the client computer is not connected to their local area network or the network is not connected to the internet a lot of time can be wasted attempting to send an email or $logon to a database. To test for a connection to the internet you could use a server which you know responds to TCPPing, and in case that server happens to be down, you could try a series of 2 or 3 servers which you know to respond to TCPPing.

; Test with the a host server that we know does not respond to TCPPing.
Calculate HostName as 'apple.com'

; (Hostname[,Size,Timeout])
; Cut the default size and timeout to reduce the TCPPing wait time.
Calculate Size as 256/4
Calculate Timeout as 3000/10
TCPPing (HostName,Size,Timeout) Returns Milliseconds
If Milliseconds<0
   
   ; Try another known domain.
   Calculate HostName as 'scsinternet.com'
   TCPPing (HostName,Size,Timeout) Returns Milliseconds
   If Milliseconds<0
      
      ; Test with the vencor.ca domain.
      Calculate HostName as 'vencor.ca'
      TCPPing (HostName,Size,Timeout) Returns Milliseconds
      
   End If
End If
If Milliseconds<0
   OK message TCPPing (Icon) {TCPPing to [HostName] failed.}
Else
   OK message TCPPing (Icon) {TCPPing to [HostName] succeeded.}
End If

Whois

You can use the TCP commands to get whois information on a domain.

; Samplecode to query the whois database with omnis
; based on the examples in the Omnis helpfile RRG / 08/03/14

; the whois server : more here : http://www.addspice2life.com/2008/02/whois-servers-list.html or http://www.mit.edu/afs/athena/contrib/potluck/Net-Services/whois-servers.list
; internic.net
; http://www.netdemon.net/tutorials/whois.txt
; http://www.iana.org/domains/root/db/index.html

Calculate WhoisDomain as 'whois.internic.net'
Calculate Port as 43 ;; Port for the whois server
Calculate TestDomain as 'omniscentral.com'
Calculate SendMssg as con(TestDomain,kCr,kLf) ;; append querystring for whois server

TCPConnect (WhoisDomain,Port) Returns Socket
If Socket<0
   OK message {Unable to TCPConnect with '[WhoisDomain]' on port [Port]}
Else
   
   ; Connected
   TCPSend (Socket,SendMssg) Returns CharCount
   TCPReceive (Socket,ReceiveMssg)
   TCPClose (Socket)
   
   Calculate ShortMssg as mid(ReceiveMssg,pos('Domain Name:',ReceiveMssg))
   
   OK message {Whois result for '[TestDomain]' is////[ShortMssg]}
   
End If

Ultra-Thin Client

Ultra-thin client is delivering html-based code from the Omnis web server to the clients. An ultra-thin client solution does not use the Omnis Web Client plugin.

The Omnis Web Server is sitting on the server listening on port 5912 (or whatever port you set it to). It can receive messages from html pages specifying the web client plug-in, or it can receive messages from html pages not using the web client plug-in.

Using the web client plug-in you can quickly create very rich browser windows. That is, browser windows which are similar to the window classes that you creating in Omnis Studio.

However, in my opinon, the Omnis Web Client solution is not great for the general public.

1. It requires users to download and install the Web Client plug-in.
2. Every time you use a new component, the plug-in asks the user if it is okay to download the component.
3. Licensing can get expensive because each simultaneous Web Client connection requires a separate runtime license.

Where you have a web page that is targeted to the general public, it is quite easy to create an HTML form that can submit data to a remote task in your Omnis web application, and then from the remote task reply to the web page with HTML.

Web Client

I started into my first Omnis Web Client job as a web server dummy. My knowledge of how the internet, browsers, and web servers worked was (and still is) pretty sparse. I had not written a single line of JavaScript and always depended on Adobe GoLive for doing all my website/HTML work.

Getting into all of this was intimidating because of my lack of knowledge and the thought of having to slow down and battle my way through yet another learning curve.

Well, hats off to OMST! The learning curve was pretty short and before I knew it my first Omnis Web Client page was up and running. Not bug free, but hey, it worked.

Two more days of digging around and I had a thin-client HTML search page communicating with a remote task in my application through the Omnis Web Server. I was impressed! (My wife's eyes glazed over when I communicated my excitement to her.)

So, if I can get the Omnis Web Server/Web Client/Thin-client stuff working, so can you!

This section doesn't try to replace the Developing Web Applications in OMST manual. Like other sections in StudioTips, this section is intended to expand on places where you might get stuck, things to watch out for, and examples and code you can that can help you when developing your own web client application.

Hope it helps!

Web Client Testing

One of the first things to do before you start programming for the web client, is to make sure the web client is installed and working for your browser.

Web Client Programming

Web Client Gotchas

When you move in the Web Client world, there are some gotchas you need to be aware of. This list of gotchas is being added to as I run into them. You may find that more recent versions of Omnis Studio have solved some of these gotchas, so be sure to test them yourself.